
**Year-over-year-to-date growth**

Year-over-year-to-date growth compares the year-to-date at a specific date with the year-to-date in an equivalent month in the previous year. Figure 7 shows that Sales PYTD in 2009 is taking into account transactions only until August 2008. For this reason, Sales YTD of Q3-2008 is 7,129,971.53, whereas Sales PYTD for Q3-2009 is less: 6,166,534.30.

Sales PYTD filters the previous value in Year and all the months in the year less than or equal to the last month visible in the filter context:

Sales PYTD :=

VAR LastMonthInYearAvailable = MAX ( 'Date'[Month Number] )

VAR LastYearAvailable = SELECTEDVALUE ( 'Date'[Year] )

VAR PreviousYearAvailable = LastYearAvailable - 1

VAR Result =

    CALCULATE (

        [Sales Amount],

        REMOVEFILTERS ( 'Date' ),

        'Date'[Month Number] <= LastMonthInYearAvailable,

        'Date'[Year] = PreviousYearAvailable

    )

RETURN

    Result

Sales YOYTD and Sales YOYTD % rely on Sales PYTD to provide their result:

Sales YOYTD :=

VAR ValueCurrentPeriod = [Sales YTD]

VAR ValuePreviousPeriod = [Sales PYTD]

VAR Result =

    IF (

        NOT ISBLANK ( ValueCurrentPeriod ) && NOT ISBLANK ( ValuePreviousPeriod ),

        ValueCurrentPeriod - ValuePreviousPeriod

    )

RETURN

    Result

Sales YOYTD % :=


DIVIDE (

    [Sales YOYTD],

    [Sales PYTD]

)

Year-over-year-to-date growth compares the year-to-date at a specific date with the year-to-date at an equivalent date in the previous year.



Sales PYTD uses [**DATEADD**](https://dax.guide/dateadd/?aff=dax-patterns) and filters the Date[DateWithSales] column to guarantee a fair comparison of the last period with data. Sales YOYTD and Sales YOYTD % rely on Sales PYTD to guarantee the same fair comparison:

Sales PYTD :=

IF (

    [ShowValueForDates],

    CALCULATE (

        [Sales YTD],

        CALCULATETABLE (

            DATEADD ( 'Date'[Date], -1, YEAR ),

            'Date'[DateWithSales] = TRUE

        )

    )

)

Sales YOYTD :=

VAR ValueCurrentPeriod = [Sales YTD]

VAR ValuePreviousPeriod = [Sales PYTD]

VAR Result =

    IF (

        NOT ISBLANK ( ValueCurrentPeriod )

            && NOT ISBLANK ( ValuePreviousPeriod ),

        ValueCurrentPeriod - ValuePreviousPeriod

    )

RETURN

    Result

Sales YOYTD % :=

DIVIDE (

    [Sales YOYTD],

    [Sales PYTD]

)

Sales PYTD shifts the date filter back one year by using [**DATEADD**](https://dax.guide/dateadd/?aff=dax-patterns). Using [**DATEADD**](https://dax.guide/dateadd/?aff=dax-patterns) makes it easy to apply shifts of two or more years. However, to shift dates back by one year Sales PYTD can also be written using [**SAMEPERIODLASTYEAR**](https://dax.guide/sameperiodlastyear/?aff=dax-patterns) as in the following example, which internally uses [**DATEADD**](https://dax.guide/dateadd/?aff=dax-patterns) as in the previous example:

Sales PYTD (2) :=

IF (

    [ShowValueForDates],

    CALCULATE (

        [Sales YTD],

        CALCULATETABLE (

            SAMEPERIODLASTYEAR ( 'Date'[Date] ),

            'Date'[DateWithSales] = TRUE

        )

    )

)